home *** CD-ROM | disk | FTP | other *** search
/ PD Collection CD 1 / PD Collection CD 1.iso / textual / tex / files / !tex / mfinputs / itall / mf
Encoding:
Text File  |  1988-02-26  |  20.1 KB  |  461 lines
  1. % This is ITALL.MF in text format, as of Mar 31, 1986.
  2. % Computer Modern Italic lower case:
  3. % This lowercase italic alphabet was prepared by D. E. Knuth in December, 1979,
  4. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  5. % The programs were revised for the new \MF\ conventions in 1985.
  6.  
  7. % Character codes \0141 through \0172 are generated.
  8.  
  9. cmchar "Italic letter a";
  10. beginchar("a",9u#,x_height#,0);
  11. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  12. adjust_fit(0,0); pickup fine.nib;
  13. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  14. pos4(stem,0); x4=x0; y4+.5stem=vround .98h;
  15. x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  16. rt x4r=hround(w-2.5u+.5stem);
  17. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  18. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  19.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  20. x5=x4; x7=w; hook_out(5,6,7);  % closing hook
  21. filldraw circ_stroke z4e--z5e;  % stem
  22. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  23. penlabels(0,1,2,3,4,5,6,7); endchar;
  24.  
  25. cmchar "Italic letter b";
  26. beginchar("b",8u#,asc_height#,0);
  27. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  28. adjust_fit(0,0); pickup tiny.nib;
  29. pos1(stem,0); pos2(stem,0); x1=x2;
  30. lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
  31. filldraw stroke z1e--z2e;  % stem
  32. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  33. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  34. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  35. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
  36. bot y3r=-oo; top y5r=x_height+oo; y4=y2;
  37. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  38.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  39. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  40. penlabels(0,1,2,3,4,5); endchar;
  41.  
  42. cmchar "Italic letter c";
  43. beginchar("c",8u#,x_height#,0);
  44. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  45. adjust_fit(0,0); pickup fine.nib;
  46. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  47. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  48. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  49. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  50. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  51. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  52. path p; p=z4{right}..z5..z6;
  53. filldraw stroke pulled_arc.e(2,3)
  54.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  55. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  56. penlabels(0,1,2,3,4,5,6); endchar;
  57.  
  58. cmchar "Italic letter d";
  59. beginchar("d",9u#,asc_height#,0);
  60. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  61.   h#*slant+.5stem#-2u#) if math_fitting:-.5u# fi;
  62. adjust_fit(0,0); pickup fine.nib;
  63. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  64. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  65. x4+.5stem=hround(w-2.5u+.5stem);
  66. top y1r=x_height+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  67. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  68.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  69. x5=x0; x7=w; hook_out(5,6,7);  % closing hook
  70. pickup tiny.nib; pos5'(stem,0); pos4(stem,0);
  71. z5'=z5; top y4=h; filldraw stroke z4e--z5'e;  % stem
  72. sloped_serif.l(4,5',a,1/3,jut,serif_drop);  % serif
  73. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  74. penlabels(0,1,2,3,4,5,6,7); endchar;
  75.  
  76. cmchar "Italic letter e";
  77. beginchar("e",8u#,x_height#,0);
  78. italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
  79. adjust_fit(0,0); pickup fine.nib;
  80. numeric heavy_hair; heavy_hair=hround .2[hair,stem];
  81. pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
  82. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  83. x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
  84. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  85. y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
  86. top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
  87. filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
  88.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  89. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  90. penlabels(0,1,2,3,4,5,6); endchar;
  91.  
  92. cmchar "Italic letter f";
  93. beginchar("f",max(1.5u#,stem#)+max(3.5u#,2flare#),asc_height#,desc_depth#);
  94. italcorr asc_height#*slant+.75u#;
  95. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  96. numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
  97. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  98. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  99. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  100. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  101. rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
  102. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  103. y4=.25[x_height,h]; y5=.5[-d,y4];
  104. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  105. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  106. bulb(2,1,0); bulb(7,8,9);  % bulbs
  107. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  108. filldraw z4r--z5l--z5r--z4l--cycle;  % stem
  109. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  110. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  111. top y20r=top y21r=x_height;
  112. lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
  113. filldraw stroke z20e--z21e;  %  crossbar
  114. math_fit(desc_depth#*slant+u#,x_height#*slant);
  115. penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
  116.  
  117. cmchar "Italic letter g";
  118. beginchar("g",8u#,x_height#,desc_depth#);
  119. italcorr x_height#*slant+.5stem#-u#;
  120. adjust_fit(0,0); pickup fine.nib;
  121. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  122. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  123. x4+.5stem=hround(w-1.5u+.5stem);
  124. top y1r=h+oo; bot y3r=0; y0=y2=.5[y1,y3];
  125. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  126.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  127. pos4(stem,0); y4+.5stem=vround .98h;
  128. pos5(stem,0); x5=x4; y5=-1/3d;
  129. pos6(vair,-90); pos7(hair,-180); pos8(flare,-180);
  130. bot y6r=-d-oo; y8-.5flare=vround -.9d;
  131. lft x8r=hround(2u-.5flare); x6=x1; bulb(6,7,8);  % bulb
  132. filldraw circ_stroke z4e---z5e...{left}z6e;  % stem and arc
  133. math_fit(-min(.3x_height#*slant+.5curve#-u#,1.5u#-desc_depth#*slant),
  134.  ic#-1/3x_height#*slant); penlabels(0,1,2,3,4,5,6,7,8); endchar;
  135.  
  136. cmchar "Italic letter h";
  137. beginchar("h",9u#,asc_height#,0);
  138. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  139. adjust_fit(0,0); pickup tiny.nib;
  140. pos1(stem,0); pos2(stem,0); x1=x2;
  141. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  142. filldraw circ_stroke z2e--z1e;  % left stem
  143. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  144. pickup fine.nib; x4+.5stem=hround(w-2.5u+.5stem);
  145. x5=x4-.25u; ital_arch(2,3,4);  % arch
  146. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  147. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  148. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  149.  
  150. cmchar "Italic letter i";
  151. beginchar("i",5u#,min(asc_height#,10/7x_height#+.5flare#),0);
  152. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  153. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  154. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  155. hook_in(0,1,2)(skewed); hook_out(3,4,5)(skewed);  % hooks
  156. filldraw stroke z2e--z3e;  % stem
  157. pos8(flare,0); pos9(flare,90);
  158. x8=.5w if not monospace:-.4(h-x_height)*slant fi; top y9r=h+1;
  159. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  160. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  161. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  162. penlabels(0,1,2,3,4,5,8,9); endchar;
  163.  
  164. cmchar "Italic letter j";
  165. beginchar("j",5u#,min(asc_height#,10/7x_height#+.5flare#),desc_depth#);
  166. italcorr h#*slant+.5stem#-u#;
  167. adjust_fit(if monospace:2u#,.5u# else: 0,0 fi); pickup fine.nib;
  168. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(w-1.5u-.5stem);
  169. hook_in(0,1,2);  % opening hook
  170. pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  171. bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  172. x4=1/3(w-u); lft x5r=min(hround-.5u,lft x5r+x4-x5l-eps);
  173. filldraw stroke z2e---z3e...{left}z4e;  % stem and arc
  174. bulb(4,5,6);  % bulb
  175. pos8(flare,0); pos9(flare,90);
  176. rt x8r=rt x2r if not monospace:-.6(h-x_height)*slant fi; top y9r=h+1;
  177. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  178. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  179. math_fit(desc_depth#*slant,x_height#*slant+.5stem#-u#);
  180. penlabels(0,1,2,3,4,5,6,8,9); endchar;
  181.  
  182. cmchar "Italic letter k";
  183. beginchar("k",8u#,asc_height#,0);
  184. italcorr x_height#*slant;
  185. adjust_fit(0,0); pickup tiny.nib;
  186. pos1(stem,0); pos2(stem,0); x1=x2;
  187. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  188. filldraw circ_stroke z2e--z1e;  % left stem
  189. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  190. pickup fine.nib; pos3(vair,90); x3=x1; y3=bar_height;
  191. pos4(vair,90); x4=w-2u; top y4r=x_height+oo;
  192. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  193. pos5(hair,0); pos6(flare,0);
  194. rt x5r=hround(w-.5u); y5+.5flare=vround(bot y4l-.03x_height);
  195. bulb(4,5,6);  % bulb
  196. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  197. x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  198. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  199. filldraw stroke z3e{right}...z7e{down}
  200.  ...z8e{right}...{up}z9e;  % lower diagonal
  201. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  202. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  203.  
  204. cmchar "Italic letter l";
  205. beginchar("l",4u#,asc_height#,0); l_width#:=4u#;
  206. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  207.  asc_height#*slant+.5stem#-2u#) if math_fitting:+.5u# fi;
  208. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  209. x2-.5stem=hround(1.5u-.5stem); x4=w; hook_out(2,3,4);  % closing hook
  210. pickup tiny.nib; pos1(stem,0); pos2'(stem,0); z2'=z2;
  211. top y1=h; x1=x2; filldraw stroke z1e--z2e;  % stem
  212. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  213. math_fit(-.5u#,1/3x_height#*slant+.5hair#+u#); penlabels(1,2,3,4); endchar;
  214.  
  215. cmchar "Italic letter m";
  216. beginchar("m",15u#,x_height#,0);
  217. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  218. adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  219. numeric shaved_stem; shaved_stem=mfudged.stem;
  220. save stem; stem=shaved_stem;
  221. pos2(stem,0); x1=x2;
  222. if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  223. else: x0=0; lft x2l=hround(2.5u-.5stem);
  224.  hook_in(0,a,1); fi  % opening hook
  225. y2-.5stem=-oo; filldraw circ_stroke z2e--z1e;  % left stem
  226. x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  227. pos5(stem,0); y5=y2; x5=x4;
  228. filldraw circ_stroke z5e--z4e;  % middle stem
  229. x7+.5stem=hround(w-2.5u+.5stem);
  230. x8=x7-.25u; ital_arch(5,6,7);  % right arch
  231. if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  232.  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  233. else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  234. filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  235. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  236. penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;
  237.  
  238. cmchar "Italic letter n";
  239. beginchar("n",10u#,x_height#,0);
  240. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  241. adjust_fit(0,0); pickup fine.nib;
  242. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  243. hook_in(0,a,1);  % opening hook
  244. filldraw circ_stroke z2e--z1e;  % left stem
  245. x4+.5stem=hround(w-2.5u+.5stem); x5=x4-.25u; ital_arch(2,3,4);  % arch
  246. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  247. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  248. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  249. penlabels(0,a,1,2,3,4,5,6,7); endchar;
  250.  
  251. cmchar "Italic letter o";
  252. beginchar("o",9u#,x_height#,0);
  253. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  254. adjust_fit(0,0); pickup fine.nib;
  255. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  256. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  257. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  258. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  259.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  260. math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
  261.  
  262. cmchar "Italic letter p";
  263. beginchar("p",9u#,x_height#,desc_depth#);
  264. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  265. adjust_fit(0,0); pickup fine.nib;
  266. x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);  % opening hook
  267. pos4(hair,-180); pos5(vair,-90); pos6(curve,0); pos7(vair,90);
  268. x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
  269. bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
  270. filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
  271.  & pulled_arc.e(6,7) & super_arc.e(7,4);  % bowl
  272. pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
  273. z2=z2'; x3=x2; bot y3=-d; filldraw stroke z2'e--z3e;  % stem
  274. dish_serif(3,2',a,1/3,.75jut,b,1/3,jut);  % serif
  275. math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
  276.  2u#-.5stem#-desc_depth#*slant),ic#);
  277. penlabels(0,1,2,3,4,5,6,7); endchar;
  278.  
  279. cmchar "Italic letter q";
  280. beginchar("q",8u#,x_height#,desc_depth#);
  281. italcorr x_height#*slant+.5stem#-u#;
  282. adjust_fit(0,0); pickup fine.nib;
  283. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  284. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  285. x4+.5stem=hround(w-1.5u+.5stem)+eps;
  286. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  287. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  288.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  289. pickup tiny.nib; pos4(stem,0); pos5(stem,0);
  290. x4=x5; x6=x5r; top y6=h+oo; bot y4=-d;
  291. y5=ypart(((x4l,0)--(x4l,y6))intersectionpoint super_arc.r(0,1));
  292. filldraw z6{2(x5l-x6),y5-y6}...z5l---z4l--z4r--cycle;  % stem
  293. dish_serif(4,5,a,1/3,jut,b,1/3,jut);  % serif
  294. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
  295. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  296.  
  297. cmchar "Italic letter r";
  298. beginchar("r",5.5u#+max(1.75u#,flare#),x_height#,0);
  299. italcorr x_height#*slant;
  300. adjust_fit(if monospace:.25u#,.5u# else: 0,0 fi); pickup fine.nib;
  301. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(2.5u-.5stem); y3-.5stem=-oo;
  302. hook_in(0,1,2);  % opening hook
  303. filldraw circ_stroke z3e--z2e;  % left stem
  304. pos3'(hair,180); z3'=z3; pos4(vair,90); pos5(hair,0); pos6(flare,0);
  305. x4=w-.5u-max(1.75u,flare); rt x5r=hround(r-.5u); top y4r=h+oo;
  306. filldraw stroke z3'e{up}...z4e{right};  % link
  307. y6+.5flare=vround(bot y4l-.03x_height); bulb(4,5,6);  % bulb
  308. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-.5u#);
  309. penlabels(0,1,2,3,4,5,6); endchar;
  310.  
  311. cmchar "Italic letter s";
  312. beginchar("s",5.25u#+max(1.75u#,flare#),x_height#,0);
  313. italcorr x_height#*slant-.5u#;
  314. adjust_fit(0,0); pickup fine.nib;
  315. numeric theta; theta=90-angle(40u,h); slope:=-h/40u;  % angle at middle
  316. pos2(vair,-90); pos0(max(fine.breadth,ess),theta); pos7(vair,-90);
  317. x2l=x0=x7=.5w; top y2l=h+oo; bot y7r=-oo;
  318. y0-.5ess=y7l+.55(y2r-y7l-ess);
  319. lft x3l=hround u-eps; rt x6r=hround(w-.5u)+eps;
  320. x3r-x3l=x6r-x6l=hround .5[vair,ess]-fine;
  321. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  322. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  323. interim superness:=more_super;
  324. filldraw stroke super_arc.e(2,3) & z3e{down}
  325.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  326. pos1(hair,0); pos10(hround .75[hair,flare],0);
  327. pos2'(vair,90); z2'=z2;
  328. pos8(hair,-180); pos9(flare,-180);
  329. rt x10r=hround(w-u)+2eps; lft x9r=hround .5u-2eps; y10=.78h; y9=.25h;
  330. bulb(2',1,10); bulb(7,8,9);  % bulbs
  331. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  332.  
  333. cmchar "Italic letter t";
  334. beginchar("t",5.5u#,min(asc_height#,10/7x_height#),0);
  335. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.25u#);
  336. adjust_fit(if monospace:u#,u# else:0,0 fi); pickup fine.nib;
  337. pos1(stem,0); lft x1l=hround(2u-.5stem); y1+.5stem=h+oo;
  338. x2=x1; x4=w; hook_out(2,3,4);  % closing hook
  339. filldraw circ_stroke z1e--z2e;  % stem
  340. pickup crisp.nib; pos5(bar,90); pos6(bar,90);
  341. lft x5=hround-.75u; rt x6=hround(w-.75u); top y5r=top y6r=x_height;
  342. filldraw stroke z5e--z6e;  % crossbar
  343. math_fit(1.25u#-x_height#*slant,ic#); penlabels(1,2,3,4,5,6); endchar;
  344.  
  345. cmchar "Italic letter u";
  346. beginchar("u",9.5u#,x_height#,0);
  347. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  348. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  349. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  350. hook_in(0,1,2)(skewed);  % opening hook
  351. pos2'(stem,-180); z2'=z2;
  352. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  353. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  354. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  355. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  356. filldraw stroke z2'e{-u,-x_height}
  357.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  358. filldraw circ_stroke z6e--z7e;  % right stem
  359. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  360. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  361.  
  362. cmchar "Italic letter v";
  363. beginchar("v",8u#,x_height#,0);
  364. italcorr x_height#*slant;
  365. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  366. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  367. hook_in(0,1,2)(skewed);  % opening hook
  368. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  369. x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  370. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  371.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  372. v_bulb(5,6);  % closing bulb
  373. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  374. penlabels(0,1,2,3,4,5,6); endchar;
  375.  
  376. cmchar "Italic letter w";
  377. beginchar("w",12u#,x_height#,0);
  378. italcorr x_height#*slant;
  379. adjust_fit(if monospace:-1.5u#,-u# else: 0,0 fi);
  380. pickup fine.nib; interim superness:=more_super; begingroup
  381. forsuffixes $=hair,stem: shaved$:=mfudged$; save $; $=shaved$; endfor
  382. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  383. if monospace: pos1(vair,90); x1=good.x .5[x0,x2]; top y1r=h; y2=2/3h;
  384.  pos2(stem,0); filldraw stroke z1e{right}...{-u,-x_height}z2e;
  385. else: hook_in(0,1,2)(skewed); fi  % opening hook
  386. pos2'(stem,-180); z2'=z2;
  387. pos4(vair,-90); pos5(hair,0);
  388. x4=.6[x2,x5]; x5=x6=x7; pos6(stem,-180); pos7(stem,-180);
  389. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  390. rt x6l=hround(rt x6l+.5w+.75u-x6); y6+.5stem=h; y7=y3;
  391. pos8(vair,-90); pos9(hair,0);
  392. x8=w-2.75u; rt x9r=hround(w-.5u); bot y8r=-oo; y9=y5;
  393. filldraw stroke z2'e{-u,-x_height}
  394.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  395. filldraw circ_stroke z6e..super_arc.e(7,8)...{up}z9e;  % middle stem and arc
  396. v_bulb(9,10);  % closing bulb
  397. endgroup; math_fit(-2/3x_height#*slant+.5hair#+.5u#,3/4ic#);
  398. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  399.  
  400. cmchar "Italic letter x";
  401. beginchar("x",6.5u#+max(1.5u#,flare#),x_height#,0);
  402. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant+.25u#);
  403. adjust_fit(0,0); pickup fine.nib;
  404. pos0(hair,180); pos1(vair,90); pos2(stem,0);
  405. pos3(stem,-180); pos4(vair,-90); pos5(hair,0);
  406. y0=y2=2/3h; y3=y5=1/3h; top y1r=h+oo; bot y4r=-oo;
  407. rt x2r=hround(.5w+.5stem-eps); x2=x3;
  408. x0-.5hair=hround-.5hair; x5+.5hair=hround(w+.5hair-eps);
  409. x1=.5[x0,x2]; x4=.5[x3,x5];
  410. filldraw stroke z0e{up}...pulled_arc.e(1,2); % opening hook
  411. filldraw z2l--z3r--z3l--z2r--cycle;  % stem
  412. filldraw stroke pulled_arc.e(3,4)...{up}z5e;  % closing hook
  413. pos3'(hair,180); pos6(hair,180); pos7(vair,90);
  414. pos8(hair,0); pos9(flare,0);
  415. x3'l=x6l=x3l; y3'=y3; y6=3/4h; x7=.5[x8,x2]; top y7r=h+oo;
  416. rt x8r=hround(w-.25u); y8+.5flare=vround(bot y7l-.03x_height);
  417. filldraw stroke z3'e---z6e...{right}z7e; bulb(7,8,9);  % upper link and bulb
  418. pos2'(hair,0); pos16(hair,0); pos17(vair,-90);
  419. pos18(hair,-180); pos19(flare,-180);
  420. x2'l=x16l=x2l; y2'=y2; y16=1/4h; x17=.5[x18,x3]; bot y17r=-oo;
  421. lft x18r=hround.25u; y18-.5flare=vround(top y17l+.03x_height);
  422. filldraw stroke z2'e---z16e...{left}z17e; bulb(17,18,19); % lower link and bulb
  423. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,16,17,18,19); endchar;
  424.  
  425. cmchar "Italic letter y";
  426. beginchar("y",8.5u#,x_height#,desc_depth#);
  427. italcorr x_height#*slant+.5stem#-u#;
  428. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  429. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  430. hook_in(0,1,2)(skewed);  % opening hook
  431. pos2'(stem,-180); z2'=z2;
  432. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  433. pos6(stem,0); rt x6r=hround(w-1.5u+.5stem);
  434. pos7(stem,0); pos8(vair,-90);
  435. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  436. y7=0; bot y8r=-d-oo; x5=x6=x7; x8=.5w;
  437. pos9(hair,-180); pos10(flare,-180); y9=-.5d;
  438. lft x9r=hround(2.75u-.5flare); bulb(8,9,10);  % bulb
  439. filldraw stroke z2'e{-u,-x_height}
  440.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  441. filldraw circ_stroke z6e---z7e...{left}z8e;  % right stem and link
  442. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  443. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  444.  
  445. cmchar "Italic letter z";
  446. beginchar("z",5.5u#+max(1.5u#,stem#),x_height#,0);
  447. italcorr x_height#*slant+.5hair#;
  448. adjust_fit(if monospace:.5u#,.5u# else: 0,0 fi); pickup fine.nib;
  449. pos1(hair,0); pos2(stem,-90); pos3(vair,-90); pos4(hair,0);
  450. lft x1l=hround(u-.5hair); x2=2.5u; x3=w-2u; rt x4r=hround(w-.5u);
  451. top y1=.78h; top y2l=top y4=h+oo; y3=.825h;
  452. pos5(hair,0); pos6(vair,-90); pos7(stem,-90); pos8(hair,0);
  453. x5=x1; x6=2.5u; x7=w-2u; x8+.5hair=hround(w+.5hair-eps);
  454. bot y5=bot y7r=-oo; y6=.175h; bot y8=.31h;
  455. pair p; p=(z4-z5) yscaled 2;
  456. filldraw stroke z1e{up}...z2e{right}..z3e{right}...{p}z4e;  % upper bar
  457. filldraw stroke z5e{p}...z6e{right}..{right}z7e...{up}z8e;  % lower bar
  458. filldraw stroke z5e{p}..{p}z4e;  % diagonal
  459. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  460. penlabels(1,2,3,4,5,6,7,8); endchar;
  461.